Поиск компьютеров с запущенным приложением
Для реализации этого скрипта используются утилиты из пакета PSTools. Создадим командный файл, выполняющий поиск в локальной сети компьютеров с выполняющейся программой, имя которой (начальная часть имени) задается в качестве параметра при запуске, например, game . При обнаружении будет послано сообщение на компьютер ADMINCOMP и обнаруженное приложение будет принудительно завершено. Для поиска будем использовать утилиту Pslist.exe и анализировать ее код возврата. Значение переменной ERRORLEVEL равное нулю означает, что утилита обнаружила на удаленном компьютере процесс, удовлетворяющий условиям поиска. Имя процесса для поиска будем задавать в качестве параметра при запуске командного файла. Присвоим нашему командному файлу имя psl.bat. Запуск с параметром будет выглядеть следующим образом:
psl.bat game
Для начала, нужно проверить, задан ли параметр в командной строке при запуске, и, если не задан, выдадим сообщение пользователю и завершим выполнение. Если же параметр задан – перейдем на метку ” PARMOK “:
@echo off
if “%1” NEQ “” GOTO PARMOK
ECHO Нужно задать имя процесса для поиска
exit
:PARMOK
Теперь нужно обеспечить последовательное формирование IP-адресов компьютеров для командной строки PSlist. Проще всего это сделать с помощью присвоения временной переменной окружения (действительной только на время выполнения командного файла) значения постоянной составляющей адреса (например – 192.168.0.) и вычисляемого значения младшей части (например, в диапазоне 1-254). Для примера будем считать, что нам необходимо просканировать компьютеры в диапазоне адресов:
192.168.0.1 – 192.168.0.30:
set IPTMP=192.168.0. – старшая часть адреса
set /A IPLAST=1 – младшая часть. Ключ /A означает вычисляемое числовое выражение
set IPFULL=%IPTMP%%IPLAST% – значение полного IP-адреса.
Командная строка для PSlist будет выглядеть cледующим образом:
pslist \\%IPFULL% %1
Теперь осталось только циклически запускать PSlist, прибавляя в каждом цикле единицу к младшей части адреса, пока ее значение не достигнет 30 и анализировать значение ERRORLEVEL после выполнения. Для анализа результата будем выполнять переход командой:
GOTO REZULT%ERRORLEVEL%
обеспечивающей переход на метку REZULT0 при обнаружении процесса и на REZULT1 – при его отсутствии.
Окончательное содержимое командного файла:
@echo off
if “%1” NEQ “” GOTO PARMOK
ECHO Нужно задать имя процесса для поиска
exit
:PARMOK
set IPTMP=192.168.0.
rem Зададим начальное значение ” хвоста ” IP- адреса
set /A IPLAST=1
rem M0 – метка для организации цикла
:M0
rem Переменная IPFULL – полное значение текущего IP-адреса
set IPFULL=%IPTMP%%IPLAST%
rem Если ” хвост “больше 30 – на выход
IF %IPLAST% GTR 30 GOTO ENDJOB
pslist \\%IPFULL% %1
GOTO REZULT%ERRORLEVEL%
:REZULT0
rem Если найдено приложение- отправим сообщение на ADMINCOMP
net send ADMINCOMP Запущено %1 – %IPFULL%
rem И завершим приложение с помощью PSkill
pskill \\%IPFULL% %1
:REZULT1
rem Сформируем следующий IP-адрес
set /A IPLAST=%IPLAST% + 1
rem Перейдем на выполнение следующего шага
GOTO M0
rem Завершение работы
:endjob
exit
В заключение добавлю, что для того, чтобы этот скрипт работал, PSlist.exe и PSkill.exe должны быть доступны в путях поиска исполняемых файлов, например в каталоге WINDOWS\SYSTEM32. Пользователь, запускающий его, должен обладать правами администратора по отношению к сканируемым компьютерам. И, если текущий пользователь таковым не является, то в параметры запуска утилит PSlist.exe и PSkill.exe нужно добавить ключи, задающие имя пользователя и пароль.
Поиск компьютеров с запущенным приложением по списку
В предыдущем примере использовался прямой перебор IP-адресов компьютеров в локальной сети, что не всегда удобно, поскольку в процедуру опроса оказываются вовлечены и выключенные компьютеры. Решим задачу другим способом. Создадим текстовый файл со списком компьютеров и опросим их по этому списку.
Список можно получить из сетевого окружения с использованием команды:
net.exe view > comps.txt
После выполнения такой команды файл comps.txt будет содержать список следующего вида:
Имя сервера Заметки
< 2 пустых строки >
——————————————————————————-
\\AB1
\\AB2
\\ALEX
\\BUHCOMP
\\PC2
\\SA
\\SERVER
Команда выполнена успешно.
Обрабатывать содержимое этого текстового файла будем с помощью команды FOR с ключом /F:
FOR /F [“ключи”] %переменная IN (имя файла) DO команда [параметры]
Данная команда позволяет получить доступ к строкам в текстовом файле с использованием ключей:
skip=n – пропустить n строк от начала файла (в нашем случае – 4 строки)
eol=< символ > – не использовать строки, начинающиеся с заданного символа. (в нашем случае – пропустить последнюю строку, начинающуюся с символа “К” – “Команда выполнена успешно”
tokens=n – брать для обработки n-е слово в строке (в нашем случае – 1-е слово)
Окончательный вид команды:
FOR /F “eol=К skip=4 tokens=1 ” %%I IN (comps.txt) DO (
pslist.exe -u admin -p pass %%I %1
IF NOT ERRORLEVEL 1 net.exe send ADMINCOMP %%i %1
)
 Обратите внимание – в пакетных файлах для переменных команды FOR используется два знака процента (запись %%переменная вместо %переменная) и имена переменных учитывают регистр букв (%i отличается от %I).
Работать это будет следующим образом – пропускаются первые 4 строки текстового файла со списком компьютеров, и далее в цикле переменной I присваивается значение первого слова (текст от начала строки до разделителя – пробела), выполняется утилита PSlist.exe, для которой в качестве имени компьютера используется значение этой переменной. Если ERRORLEVEL менее 1 – задача с искомым именем присутствует в списке процессов и выполняется отправка сообщения с помощью NET SEND.
Окончательное содержимое командного файла:
@echo off
if “%1” NEQ “” GOTO PARMOK
ECHO Нужно задать имя процесса для поиска
exit
:PARMOK
REM
REM Создадим текстовый файл comps.txt со списком компьютеров с помощью NET.EXE VIEW
net view /DOMAIN:MyDomain > comps.txt
REM
REM FOR /F “параметры” – использование данных из файла
REM eol=К – не использовать строки, начинающиеся с “К” – “Команда выполнена успешно”
REM skip=4 – пропустить первые 4 строки в файле
REM tokens=1 – брать для обработки 1-е слово в строке
REM
FOR /F “eol=К skip=4 tokens=1 ” %%i in (comps.txt) do (
pslist.exe -u admin -p pass %%i %1
IF NOT ERRORLEVEL 1 net.exe send %COMPUTERNAME% Компьютер – %%i процесс – %1
)
Выключение компьютеров по списку, созданному на основе сетевого окружения.
Предыдущий пример натолкнул меня на мысль сделать пакетный файл для быстрого выключения всех компьютеров в сети. Выключение производится утилитой PsShutdown.exe (описание в статье “Утилиты пакета PSTools”). Как и в предыдущем примере, сначала создается файл со списком компьютеров на основе сетевого окружения, а затем выполняется их поочередное выключение, при условии, что компьютер не свой (иначе он может выключиться до окончания выполнения командного файла). Содержимое файла:
rem @echo off
REM Здесь нужно задать
REM имя домена или рабочей группы для которых строится список машин для выключения
set MyDomain=имя домена
REM
REM Создадим текстовый файл comps.txt со списком компьютеров с помощью NET VIEW
net view /DOMAIN:%MyDomain% > comps.txt
REM
REM FOR /F “параметры” – использование данных из файла
REM eol=К – не использовать строки, начинающиеся с “К” – “Команда выполнена успешно”
REM skip=4 – пропустить первые 4 строки в файле
REM tokens=1 – брать для обработки 1-е слово в строке
FOR /F “eol=К skip=4 tokens=1 ” %%i in (comps.txt) do (
REM Свой компьютер выключать не будем
REM Если имя компьютера не равно COMPUTERNAME – выключаем
IF /I %%i NEQ %COMPUTERNAME% psshutdown -k -t 0 %%i
)
Вам нужно только подредактировать строку:
set MyDomain=
указав имя домена и, при необходимости, добавить параметры -u -p для psshutdown.exe .
В реальной жизни из списка выключаемых компьютеров нужно исключить несколько штук, для чего удобно использовать команду FIND в цепочке с net.exe в скрипте формирования списка на основе сетевого окружения. Данная команда используется для поиска строк в текстовом файле по шаблону. Ключ /V используется для поиска строк не совпадающих с шаблоном. Для выключения компьютеров, исключая server1…server4 удобно использовать такой вариант:
net view | find “\\” | find /v “сервер1” | find /v “сервер2” | find /v “сервер3” | find /v “сервер4” > comps.txt
FOR /F “tokens=1 ” %%i in (comps.txt) do shutdown.exe -f -s -m %%i
Работа с графическими приложениями Windows.
Допустим, вам нужно из одного и того же командного файла запустить noteped.exe и cmd.exe. Если просто вставить строки
notepad.exe
cmd.exe
то после запуска notepad.exe выполнение командного файла приостановится и пока не будет завершен notepad, cmd.exe не запустится. Самый простой способ обойти эту проблему – использовать стандартную утилиту Windows start.exe. Полную справку по использованию можно получить по:
start.exe /?
Попробуйте создать командный файл следующего содержания:
start /MAX notepad.exe
start “This is CMD.EXE” /MIN cmd.exe
net send %COMPUTERNAME% NOTEPAD and CMD running.
После выполнения этого командного файла вы увидите стартовавшие, в развернутом окне (ключ /MAX) блокнот, в свернутом окне (ключ /MIN) командный процессор CMD.EXE и окно с сообщением net.exe. Стандартный заголовок окна cmd.exe заменен на текст “This is CMD.EXE”. Обратите внимание на то что заголовок окна можно опускать, но особенность обработки входных параметров утилитой start.exe может привести к неожиданным результатам при попытке запуска программы, имя или путь которой содержит пробел(ы). Например при попытке выполнить следующую команду:
start “C:\Program Files\FAR\FAR.EXE”
Из-за наличия пробела в пути к исполняемому файлу, строка для запуска FAR.EXE должна быть заключена в двойные кавычки, однако формат входных параметров для start.exe предполагает наличие заголовка окна, также заключаемого в двойные кавычки, в результате чего “C:\Program Files\FAR\FAR.EXE” интерпретируется не как исполняемая программа, а как заголовок окна. Для того, чтобы подобного не случилось нужно использовать любой, пусть даже пустой, заголовок:
start “” “C:\Program Files\FAR\FAR.EXE”
Если вам все же потребуется расширенное управление окнами приложений, придется воспользоваться сторонним программным обеспечением, например, CMDOW Скачать ~15кб
Сайт разработчика
Из-за специфического поведения эта утилита большинством антивирусов определяется как вирус, поэтому для нормальной работы нужно занести ее в исключения антивируса.
Cmdow.exe – крошечная утилита, работающая в Windows NT4/2000/XP/2003 без установки. Позволяет получить список окон, перемещать, изменять размеры, переименовывать, сворачивать/разворачивать, активировать/деактивировать, закрывать, скрывать окна приложений и многое другое. Справку можно получить по команде:
cmdow /?
Используется около 30 ключей. Описание на русском языке найдете здесь. Некоторые примеры:
Получение информации об окнах:
cmdow.exe или cmdow.exe > wins.txt – выдать инвормацию обо всех окнах на экран или в файл wins.txt
cmdow /T – выдать информацию об окнах, отображаемых на панели задач рабочего стола.
Информация содержит колонки:
Handle – дескриптор окна – шестнадцатиричное число, связанное с данным окном.
Lev – уровень окна. Приложение может быть многооконным с несколькими уровнями окон.
Pid – идентификатор процесса, породившего окно.
-Window status- – состояние окна (видимое – Vis, скрытое – Hid, активное – Act, свернутое – Min и т.п.
Image – программа вызвавшая окно.
Caption – название окна
Манипулировать окнами можно используя название окна, или его дескриптор. Если название окна содержит пробелы, то оно заключается в двойные кавычки. Если имеются русские буквы, то должна использоваться DOS-кодировка. Символ @ используется для указания текущего окна. Иногда проще использовать дескриптор окна, а не его название. Полезным может быть и использование команды поиска по строке find.exe, выполняемой в цепочке с cmdow:
cmdow.exe | find.exe /I “hid” > wins.txt – в файл wins.txt попадут только строки содержащие шаблон “hid” и мы получим список скрытых окон.
cmdow.exe | find.exe /I “MyIE” > wins.txt – список окон приложения MyIE
Манипулирование окнами.
Если вы хотите, чтобы ваш командный файл выполнялся скрытно, добавьте в него строку:
cmdow @ /HID – скрыть текущее окно
Ниже командный файл с комментариями, демонстрирующий возможности работы cmdow:
@ECHO OFF
REM Свернуть все окна – /MA
cmdow /MA
REM запустить cmd.exe с заголовком окна MyCMD
start “MyCMD” cmd.exe
REM ждать 5 секунд
call :wait5s
REM
:M1
REM Скрыть окно MyCND
cmdow MyCMD /hid
call :wait5s
REM Сделать видимым
cmdow MyCMD /vis
call :wait5s
REM Переместить в верхний левый угол экрана и развернуть окно
cmdow MyCMD /MOV 0 0
cmdow Mycmd /max
call :wait5s
REM Изменить размер на 320 х 240 и переместить вправо на 320 точек
cmdow MyCMD /MOV 320 0 /SIZ 320 240
call :wait5s
REM Переместить окно в точку с координатами 320 x 240 и изменить размер на 350×50
cmdow MYCMD /MOV 320 240 /SIZ 350 50
call :wait5s
REM Восстановить окно
cmdow MYCMD /RES
call :wait5s
REM Восстановить и сделать активным окно этого командного файла
cmdow @ /RES /ACT
ECHO Для завершения нажмите CTRL-C (CTRL-Break)
call :wait5s
call :wait5s
REM Зацикливание – переход к метке :M1
GOTO M1
REM Подпрограмма задержки на 5секунд
:wait5s
@ping -n 5 localhost > nul
Пример командного файла, закрывающего окна Проводника Интернет (IEXPLORE.EXE):
@echo off
:M1
for /f “tokens=1-2,8” %%a in (‘cmdow’) do (
if /i “%%c”==”IEXPLORE” if “%%b”==”1” cmdow %%a /END > nul
)
goto M1
Работает это следующим образом. Из выходных данных CMDOW берется первое, второе и 8-е поля. Первое – дескриптор окна (Handle), второе – уровень (Lev), третье – имя программы (Image). В цикле выполняется cmdow и если в ее выводе имеется строка, где имя программы IEXPLORE и уровень окна 1 выполняется cmdow /END. Пока этот командный файл выполняется, запустить “Проводник интернета” не получится. А если в начало командного файла добавить “cmdow @ /hid” – то будет скрыто и его окно.
Часто встречающиеся ошибки при написании командных файлов.
- Командный файл вручную выполняется успешно, но запущенный с помощью планировщика не работает.
Обычно, это вызвано тем, что вы не учитываете тот факт, что на момент выполнения вашего командного файла переменные среды могут быть совсем другими, чем на момент его написания и запуска из командной строки. Например, в командном файле используется запуск приложения myprog.exe, находящегося в каталоге SCRIPTS на диске D: . Если в командном файле используется имя модуля без полного пути
MYPROG.EXE
и если каталог D:\SCRIPTS не прописан в путях поиска (переменная PATH ) то модуль MYPROG.EXE может быть найден и выполнен только если текущим каталогом является D:\SCRIPTS. Но если вы укажете полный путь к myprog.exe:
D:\SCRIPTS\myprog.exe
то программа будет найдена и выполнена в любом случае.
Кроме того, нередко программа, указанная в командном файле использует для поиска своих компонент (dll, ini и т.п. ) собственный каталог. Но на момент ее выполнения текущим каталогом может быть любой (чаще всего – системный каталог Windows). Естественно, компоненты не находятся и программа не выполняется. Для устранения проблемы добавьте в командный файл команды, обеспечивающие переход в нужный каталог. Например, программа myprog.exe должна выполняться в каталоге D:\SCRIPTS:
Rem Сменим текущий диск
D:
Rem перейдем в каталог SCRIPTS
CD D:\SCRIPTS
myprog.exe
Неправильно отображаются русские имена файлов, служб и т.п.
Причина в том, что при создании командных файлов вы использовали текстовый редактор, в котором русские символы представлены не в DOS-кодировке. Если в приведенном выше примере перезапуска службы “DNS-клиент” вы используете неверную кодировку, то русская часть имени службы не будет опознана из-за неверной кодировки и будет выдано сообщение, что указанная служба не установлена. Чтобы избежать проблем с русскими символами в командных файлах, используйте редактор с поддержкой DOS-кодировки, например, встроенный редактор файлового менеджера FAR. Переключение между кодировками в редакторе осуществляется нажатием F8 . С помощью FAR можно легко осуществлять перекодировку, скопировав (вырезав) текст в буфер обмена, затем нажав F8 и вставив текст из буфера.
Командный файл выполняется на одном компьютере успешно, но на другом – не работает.
Обычно это вызвано применением в командных файлах абсолютных значений вместо переменных среды окружения. Вместо C:\WINDOWS правильнее использовать %SYSTEMROOT%, потому, что на другом компьютере система может быть установлена в другой каталог или на другой диск. Старайтесь вместо имени командного файла использовать переменную %0 и ее подстановочные варианты (%~d0 – диск с которого запущен сценарий, %~dp0 – полный путь и т.д.).
Строки с переменными, принимающими значения имен файлов и каталогов лучше заключать в кавычки. Командная строка
DIR %ProgramFiles%
не выдаст вам содержимого каталога C:\Program Files , поскольку из-за наличия пробела будет интерпретирована как
DIR C:\Program
Командная строка
DIR “%ProgramFiles%”
выполнится верно.
Старайтесь использовать командды Setlocal и Endlocal, чтобы не оставлять мусор из переменных, созданных или модифицированных командным файлом.<BR
Использование командных файлов в сценариях регистрации пользователей .
Командные файлы удобно использовать для выполнения каких-либо действий при регистрации пользователя в домене. Делается это с помощью вкладки Profile свойств пользователя домена.
Сами командные файлы должны находиться в сетевой папке Netlogon (WINDOWS\SYSVOL\ DOMAIN\SCRIPTS) контроллера домена.
Источник: не определен.
